windows/_mkdir.sas

Go to the documentation of this file.

 
%macro _mkdir (dir
              );

   %local xwait xsync xmin logfile;
   %let xwait=%sysfunc(getoption(xwait));
   %let xsync=%sysfunc(getoption(xsync));
   %let xmin =%sysfunc(getoption(xmin));

   options noxwait xsync xmin;

   %let logfile=%sysfunc(pathname(work))\___mkdir.txt;
   %SYSEXEC(md "&dir" > "&logfile" 2>&1);  
   
   %if &g_verbose. %then %do;
      %put ======== OS Command Start ========;

      /* Evaluate sysexec´s return code */
      %if &sysrc. = 0 %then %put &g_note.(SASUNIT): Sysrc : 0 -> SYSEXEC SUCCESSFUL;
      %else %put &g_error.(SASUNIT): Sysrc : &sysrc -> An Error occured;

      /* put sysexec command to log*/
      %put &g_note.(SASUNIT): SYSEXEC COMMAND IS: md "&dir" > "&logfile";
      
      /* write &logfile to the log*/
      data _null_;
         infile "&logfile" truncover lrecl=512;
         input line $512.;
         putlog line;
      run;
      %put ======== OS Command End ========;
   %end;

   options &xwait &xsync &xmin;

%mend _mkdir;