unix_aix/_dir.sas

Go to the documentation of this file.

 
%MACRO _dir(i_path=
           ,i_recursive=0
           ,o_out=dir
           );

   %LOCAL dirfile encoding s l_i_path;

   proc sql noprint;
      create table &o_out (filename char(255));
   quit;

   %IF (not %sysfunc (exist (&o_out))) %THEN %GOTO errexit;

   %let encoding=pcoem850;
   %let s =;
   %let dirfile=%sysfunc(pathname(work))/&o_out..dir.txt;
   filename _dirfile "&dirfile" encoding=&encoding;

/*   %put &g_note.(SASUNIT): Directory search is: &i_path;*/

   %let l_i_path=%qsysfunc(tranwrd(&i_path, %str( ), %str(\ )));

   %let search = %qscan(&l_i_path.,-1,'/');
   %let k = %index(&l_i_path.,%qtrim(&search.));
   %let path = %qsubstr(&l_i_path.,1,%eval(&k.-2));
   %if %qsubstr(&path.,1,1) eq %str(%') %then
       %let path = &path.%str(%');
   %if %qsubstr(&path.,1,1) eq %str(%") %then
       %let path = &path.%str(%");

   %SYSEXEC(find -L &path. ! -name &path -name "&search." -ls -type f > &dirfile.);

   %if &g_verbose. %then %do;
      %put ======== OS Command Start ========;
      /* Evaluate sysexec´s return code */
      %if &sysrc. = 0 %then %put &g_note.(SASUNIT): Sysrc : 0 -> SYSEXEC SUCCESSFUL;
      %else %put &g_error.(SASUNIT): Sysrc : &sysrc -> An Error occured;

      /* put sysexec command to log*/
      %put &g_note.(SASUNIT): SYSEXEC COMMAND IS: find -L &path. ! -name &path -name "&search." -ls -type f > &dirfile.;
      
      /* write &dirfile to the log*/
      data _null_;
         infile "&dirfile" truncover lrecl=512;
         input line $512.;
         putlog line;
      run;
      %put ======== OS Command End ========;
   %end;
   
   data &o_out (keep=membername filename changed );
      array dum{7} $;
      array dat{3} $;
      length filename membername $255
             temp_path temp_file $255
             fileall  $1024
             ;
      format changed datetime20.;
      infile _dirfile delimiter=' ' truncover;
      input dum1-dum7 $ dat1-dat3 $ fileall $;
      filename = fileall;
      if substr(dum3,1,1)='d' then delete;
      if index(dat3,':') gt 0 then do;
         changed = input(compress(dat2 || dat1 || year(today())) || " " || dat3, datetime.);
         if datepart(changed) gt today() then do;
            changed = input(compress(dat2 || dat1 || year(today())-1) || " " || dat3, datetime.);
         end;
      end;
      else do;
         changed =input(compress( dat2 || dat1 || dat3) || " 00:00", datetime.);
      end;
      loca = length(filename) - length(scan(filename,-1,'/')) + 1;
      membername = substr(filename,loca);

      %if &i_recursive=0 %then %do;
         temp_path = dequote("&path");
         temp_file = scan(filename,-1,"/");
         if (trim(temp_path) !! "/" !! trim(temp_file) = filename) then output;
      %end;
   run;

%errexit:
%MEND _dir;