runsasunit.sas

Go to the documentation of this file.

 
%MACRO runSASUnit(i_source     =
                 ,i_recursive  = 0
                 );
   %GLOBAL
      d_macroList
      d_listcalling
   ;
   %LOCAL 
      d_dependency
      d_dir
      d_examinee 
      d_scenariosToRun
      d_scn_pre
      i
      l_auto 
      l_autonr
      l_c_scnid
      l_dorun 
      l_error_count 
      l_filename
      l_filled
      l_lstfile
      l_macname
      l_nscn 
      l_nscncount
      l_rc
      l_result
      l_result0 
      l_result1 
      l_result2
      l_scn 
      l_scndesc
      l_scnid 
      l_scnlogfullpath
      l_source
      l_sysrc
      l_sysrc
      l_warning_count
   ;

   %LET l_macname=&sysmacroname;

   %_tempFileName(d_dependency);
   %_tempFileName(d_dir);
   %_tempFileName(d_examinee);
   %_tempFileName(d_listcalling);
   %_tempFileName(d_macroList);
   %_tempFileName(d_scenariosToRun);
   %_tempFileName(d_scn_pre);

   /*-- check if testdatabase can be accessed -----------------------------------*/
   %IF %_handleError(&l_macname.
                    ,NoTestDB
                    ,NOT %sysfunc(exist(target.tsu)) OR NOT %symexist(g_project)
                    ,%nrstr(test database cannot be accessed, call initSASUnit before runSASUnit)
                    ,i_verbose=&g_verbose.
                    )
      %THEN %GOTO errexit;

   /*-- parameter i_recursive ---------------------------------------------------*/
   %IF "&i_recursive" NE "1" %THEN %LET i_recursive=0;

   /*-- find out all test scenarios ---------------------------------------------*/
   %LET l_source = %_abspath(&g_root, &i_source);
   %_dir(i_path=&l_source, i_recursive=&i_recursive, o_out=&d_dir)
   %IF %_handleError(&l_macname.
                    ,NoSourceFiles
                    ,%_nobs(&d_dir) EQ 0
                    ,Error in parameter i_source: no test scenarios found
                    ,i_verbose=&g_verbose.
                    ) 
      %THEN %GOTO errexit;

   data &d_scn_pre.;
      set &d_dir.;
   run;

   /*-- find out all possible units under test ----------------------------------*/
   %LET l_auto=&g_sasautos;
   %LET l_autonr=0;
   %DO %WHILE("&l_auto" ne "");  
      %LET l_auto=%quote(&l_auto/);
      %_dir(i_path=&l_auto.*.sas, o_out=&d_dir);
      data &d_examinee;
         set %IF &l_autonr>0 %THEN &d_examinee; &d_dir(in=indir);
         if indir then DO;
            auton=&l_autonr.+2;
            source=symgetc ("l_auto");
         end;
      run; 
      %LET l_autonr = %eval(&l_autonr+1);
      %LET l_auto=;
      %IF %symexist(g_sasautos&l_autonr) %THEN %LET l_auto=&&g_sasautos&l_autonr;
   %END;
   %IF (&g_crossrefsasunit.) %THEN %DO;
      %LET l_auto=&g_sasunit;
      %LET l_auto=%quote(&l_auto/);
      %_dir(i_path=&l_auto.*.sas, o_out=&d_dir);
      data &d_examinee;
         set &d_examinee &d_dir(in=indir);
         if indir then DO;
            auton=0;
            source=symgetc ("l_auto");
         end;
      run; 
      %LET l_auto=&g_sasunit_os;
      %LET l_auto=%quote(&l_auto/);
      %_dir(i_path=&l_auto.*.sas, o_out=&d_dir);
      data &d_examinee;
         set &d_examinee &d_dir(in=indir);
         if indir then DO;
            auton=1;
            source=symgetc ("l_auto");
         end;
      run; 
   %END;

   /* Create cross-reference */
   %_crossreference(i_includeSASUnit = &g_crossrefsasunit.
                   ,i_examinee       = &d_examinee.
                   ,o_listcalling    = &d_listcalling.
                   ,o_dependency     = &d_dependency.
                   ,o_macroList      = &d_macroList.
                   );

   /* check which test scenarios must be run */
   %_checkScenario(i_examinee        = &d_examinee.
                  ,i_scn_pre         = &D_SCN_PRE.
                  ,i_dependency      = &d_dependency.
                  ,i_scenariosToRun  = &d_scenariosToRun.
                  );

   /*-- if scenario already exists and has been changed: delete scenario files-----*/
   %_deletescenariofiles(i_scenariosToRun=&d_scenariosToRun.
                        );

   PROC SQL NOPRINT;
      DELETE * FROM target.cas WHERE cas_scnid in (select scn_id from &d_scenariosToRun where dorun=1);
      DELETE * FROM target.tst WHERE tst_scnid in (select scn_id from &d_scenariosToRun where dorun=1);
   QUIT;

   /*-- if scenario not present in test database: create new scenario --------*/
   DATA target.scn;
      SET target.scn &d_scenariosToRun(where=(insertIntoDB=1) in=add);
      IF add=1 THEN DO;
         scn_path = resolve('%_stdPath(&g_root,' || filename || ')');
         drop filename dorun insertIntoDB name;
      END;
   RUN;
   
   /* Prepare Loop */
   PROC SQL noprint;
      select count(scn_id) into :l_nscn
         from &d_scenariosToRun
      ;
   QUIT;

   /*-- loop over all test scenarios --------------------------------------------*/
   %DO i=1 %TO &l_nscn;

      DATA _NULL_;
         in = &i.;
         set &d_scenariosToRun point=in;
         Call Symputx('l_scnid',scn_id, 'L');
         Call Symputx('l_dorun',dorun, 'L');
         Call Symputx('l_filename',filename, 'L');
         stop;
      RUN;

      %LET l_scn = %_stdPath(&g_root,&l_filename);

      %IF &l_dorun %THEN %DO;
         %PUT ======== test scenario &l_scnid (&l_scn) will be run ========;
         %PUT;
         %PUT;
      %END;
      %ELSE %DO;
         %PUT ======== test scenario &l_scnid (&l_scn) will not be run ==;
         %PUT;
         %PUT;
      %END;

      /*-- start test scenario if necessary -------------------------------------*/
      %IF &l_dorun %THEN %DO;

         /*-- save description and start date and time of scenario --------------*/
         %_getPgmDesc (i_pgmfile=&l_filename, r_desc=l_scndesc)
         PROC SQL NOPRINT;
            UPDATE target.scn SET
               scn_desc  = "&l_scndesc"
              ,scn_start = %sysfunc(datetime())
            WHERE scn_id = &l_scnid
            ;
         QUIT;
       
         %LET l_c_scnid        = %substr(00&l_scnid.,%length(&l_scnid));
         %LET l_scnlogfullpath = &g_log/&l_c_scnid..log;
         %_runProgramSpawned(i_program          =&l_filename
                            ,i_scnid            =&l_c_scnid.
                            ,i_generateMcoverage=&g_testcoverage.
                            ,r_sysrc            =l_sysrc
                            );    
                     
         /*-- delete listing if empty -------------------------------------------*/
         %LET l_filled=0;
         %LET l_lstfile=&g_testout/%substr(00&l_scnid,%length(&l_scnid)).lst;
         %IF %SYSFUNC(FILEEXIST("&l_lstfile")) %THEN %DO;
           DATA _null_;
              INFILE "&l_lstfile";
              INPUT;
              CALL symput ('l_filled','1');
              STOP;
           RUN;
         %END;
         %IF NOT &l_filled %THEN %DO;
            %LET l_filled=%_delfile(&l_lstfile);
         %END;

         /*-- save metadata of test scenario ------------------------------------*/
         /* scan log for errors outside test cases */
         %_checklog (
             i_logfile = &l_scnlogfullpath.
            ,i_error   = &g_error.
            ,i_warning = &g_warning.
            ,r_errors  = l_error_count
            ,r_warnings= l_warning_count
         )

         PROC SQL NOPRINT;
            /* determine results of the test cases */
            %*** Treat missing scenario as error ***;
            %let l_result=2;

            SELECT max (cas_res) INTO :l_result FROM target.cas WHERE cas_scnid=&l_scnid;

            %*** Treat missing scenario as failed and treat scenario with errors in scenario log as failed ***;
            %if (&l_result. = . or &l_error_count. > 0) %then %let l_result=2;
            
            UPDATE target.scn
               SET 
                   scn_end          = %sysfunc(datetime())
                  ,scn_rc           = &l_sysrc.
                  ,scn_errorcount   = &l_error_count.
                  ,scn_warningcount = &l_warning_count.
                  ,scn_res          = &l_result.
               WHERE 
                  scn_id = &l_scnid.
               ;

            UPDATE &d_scenariosToRun
               SET 
                   dorun          = 0
               WHERE 
                  scn_id = &l_scnid.
               ;         QUIT;

      %END; /* run scenario */
   %END; /* loop for all scenarios */

   %GOTO exit;
%errexit:
      %PUT;
      %PUT =========================== Error! runSASUnit aborted! ==========================================;
      %PUT;
      %PUT;

      %IF %EVAL("%UPCASE(&g_error_code.)" EQ "%UPCASE(NoSourceFiles)") %THEN %DO;

         /* ensure that dummy entry for inexisting scenario is present in test database, to be able to report it later
         */
         %LET l_scn = %_stdPath(&g_root., &l_source.);

         %LET l_nscncount = 0;
         PROC SQL NOPRINT;
            SELECT Count(scn_id)
               INTO :l_nscncount SEPARATED BY ''
            FROM target.scn
            WHERE Upcase(scn_path) = "%UPCASE(&l_scn.)";
         QUIT;

         %IF %EVAL(&l_nscncount. EQ 0) %THEN %DO;

            %LET l_scndesc = %STR(Scenario not found - has to fail!);
           
            PROC SQL NOPRINT;
               SELECT max(scn_id) INTO :l_scnid FROM target.scn;
               %IF &l_scnid=. %THEN %LET l_scnid=0;
               %LET l_scnid = %eval(&l_scnid+1);
               INSERT INTO target.scn 
                  ( 
                    scn_id
                   ,scn_path
                   ,scn_desc
                   ,scn_start
                   ,scn_end
                   ,scn_rc
                   ,scn_errorcount
                   ,scn_warningcount
                   ,scn_res
                  )
                  VALUES 
                  (
                      &l_scnid
                     ,"&l_scn."
                     ,"&l_scndesc."
                     ,.
                     ,.
                     ,.
                     ,.
                     ,.
                     ,2
                  )
               ;
            QUIT;
         %END; /* if scenario is not present in database */
      %END;

%exit:
   PROC DATASETS NOLIST NOWARN LIB=%scan(&d_dependency,1,.);
      DELETE %scan(&d_dependency,2,.);
      DELETE %scan(&d_dir,2,.);
      DELETE %scan(&d_examinee,2,.);
      DELETE %scan(&d_scenariosToRun,2,.);
      DELETE %scan(&d_scn_pre,2,.);
   QUIT;
%MEND runSASUnit;