linux/_dir.sas

Go to the documentation of this file.

 
%MACRO _dir (i_path=
            ,i_recursive=0
            ,o_out=dir
            );

   %LOCAL dirfile encoding s l_i_path;
   
   data &o_out ;
       length filename $255;
       format changed datetime20.;
   run;
   
   %IF &syserr NE 0 %THEN %GOTO errexit;

   %LET encoding=wlatin1;
   %LET dirfile=%sysfunc(pathname(work))/.dir.txt;
   filename _dirfile "&dirfile" encoding=&encoding;
    
   %put &g_note.(SASUNIT): Directory search is: &i_path;

   %let l_i_path=%qsysfunc(tranwrd(&i_path, %str( ), %str(\ )));
   %IF &i_recursive=0 %then %let s=-maxdepth 1; 
   %SYSEXEC(find -P &l_i_path. &s. -type f -printf "%nrstr(%h/%f\t%TD\t%TT\t\r\n)" > &dirfile. 2>/dev/null);
   
   %if &g_verbose. %then %do;
      %put ======== OS Command Start ========;
      /* Evaluate sysexec´s return code */
      %if &sysrc. = 0 %then %put &g_note.(SASUNIT): Sysrc : 0 -> SYSEXEC SUCCESSFUL;
      %else %put &g_error.(SASUNIT): Sysrc : &sysrc -> An Error occured;

      /* put sysexec command to log*/
      %put &g_note.(SASUNIT): SYSEXEC COMMAND IS: find -P &l_i_path. &s. -type f -printf "%nrstr(%h/%f\t%TD\t%TT\t\r\n)" > &dirfile. 2>/dev/null;
      
      /* write &dirfile to the log*/
      data _null_;
         infile "&dirfile" truncover lrecl=512;
         input line $512.;
         putlog line;
      run;
      %put ======== OS Command End ========;
   %end;
   
   data &o_out. (keep=membername filename changed);
      length membername filename $255;
      format changed datetime20.;
      infile _dirfile delimiter='09'x truncover;
      input filename $ d:mmddyy8. t:time8.; 
      changed = dhms (d, hour(t), minute(t), 0);
      loca = length(filename) - length(scan(filename,-1,'/')) + 1;
      membername = substr(filename,loca);
   run;

   proc sort data=&o_out.;
      by filename;
   run;

%errexit:
%MEND _dir;