assertreport.sas

Go to the documentation of this file.

 
%MACRO assertReport (i_expected           =       
                    ,i_actual             =       
                    ,i_desc               = Compare documents
                    ,i_manual             = 1
                    );

   /*-- verify correct sequence of calls-----------------------------------------*/
   %GLOBAL g_inTestcase;
   %IF &g_inTestcase EQ 1 %THEN %DO;
      %endTestcall;
   %END;
   %ELSE %IF &g_inTestcase NE 2 %THEN %DO;
      %PUT &g_error.(SASUNIT): assert must be called after initTestcase;
      %RETURN;
   %END;

   %LOCAL l_expected l_exp_ext l_rep_ext l_result l_casid l_tstid l_path l_errmsg;

   %*** check parameters ***;
   %LET l_rep_ext  = %_getExtension(&i_actual);

   %IF ("&i_actual." EQ "") %THEN %DO;
      %LET l_errmsg = parameter i_actual is missing!;
      %LET l_result=2;
      %GOTO Update;
   %END;

   %IF not (%sysfunc (fileexist(&i_actual.))) %THEN %DO;
      %LET l_errmsg = File i_actual (&i_actual.) does not exist!;
      %LET l_result=2;
      %GOTO Update;
   %END;

   %IF ("&i_expected." EQ "") %THEN %DO;
      %LET l_errmsg = parameter i_expected is missing!;
   %END;
   %ELSE %DO;
      %LET l_expected = %_abspath(&g_refdata,&i_expected);
      %IF (%sysfunc (fileexist(&l_expected.))) %THEN %DO;
         %LET l_exp_ext  = %_getExtension(&l_expected);
      %END;
   %END;

   /*-- check for existence and check change date -------------------------------*/
   %LET l_result=2;
   %LET l_errmsg=Report was not created anew!;
   %local d_dir;
   %_tempFileName(d_dir)
   %_dir(i_path=&i_actual, o_out=&d_dir)
   data _null_;
      set &d_dir nobs=nobs;
      if nobs ne 1 then stop;
      if changed < dhms (today(), hour (input ("&systime",time5.)), minute (input ("&systime",time5.)), 0) then do;
         stop;
      end;
      call symput ('l_result', '1');
      stop;
   run;
   proc sql;
      drop table &d_dir;
   quit;

   %IF NOT &i_manual AND &l_result=1 %THEN %LET l_result=0;

   /*-- get current ids for test case and test --------- ------------------------*/
   %_getScenarioTestId (i_scnid=&g_scnid, r_casid=l_casid, r_tstid=l_tstid);

   %*** create subfolder ***;
   %_createTestSubfolder (i_assertType   =assertreport
                         ,i_scnid        =&g_scnid.
                         ,i_casid        =&l_casid.
                         ,i_tstid        =&l_tstid.
                         ,r_path         =l_path
                         );

   /* copy actual report if it exists */
   %IF &l_rep_ext. NE %THEN %DO;
      %_copyFile(&i_actual, &l_path./_man_act&l_rep_ext);
   %END;

   /* copy expected report if it exists  */
   %IF &l_exp_ext. NE %THEN %DO;
      %_copyFile(&l_expected, &l_path./_man_exp&l_exp_ext);
   %END;

%Update:
   %_asserts(i_type     = assertReport
            ,i_expected = &l_exp_ext.
            ,i_actual   = &l_rep_ext.
            ,i_desc     = &i_desc.
            ,i_result   = &l_result.
            ,r_casid    = l_casid
            ,r_tstid    = l_tstid
            ,i_errmsg   = &l_errmsg.
   )

%MEND assertReport;