_reportpgmdoc.sas

Go to the documentation of this file.

 
%macro _reportpgmdoc (i_language=);

   %local l_anzMacros i l_Path l_outputPath l_macroName;

   %if (%sysfunc(exist (WORK._bugdoc))) %then %do;
      proc delete data=WORK._bugdoc;
      run;
   %end;
   %if (%sysfunc(exist (WORK._testdoc))) %then %do;
      proc delete data=WORK._testdoc;
      run;
   %end;
   %if (%sysfunc(exist (WORK._tododoc))) %then %do;
      proc delete data=WORK._tododoc;
      run;
   %end;

   %_reportCreateStyle;

   proc format lib=work;
      value $HeaderText_de
         "\brief"           = "Ausführliche Beschreibung"
         "\details"         = "Ausführliche Beschreibung"
         "\author"          = "Autor"
         "\date"            = "Datum"
         "\sa"              = "Siehe auch"
         "\bug"             = "Fehler"
         "\test"            = "Austehende Tests"
         "\todo"            = "Austehende Aufgaben"
         "\version"         = "Version"
         "\param"           = "Parameter"
         "\return"          = "Rückgabe"
         "\ret_val"         = "Rückgabewert"
         "\remark"          = "Kommentar"
         "\copyright"       = "Copyright"
         "_label_todolist_" = "Austehende Aufgaben"
         "_label_testlist_" = "Austehende Tests"
         "_label_buglist_"  = "Fehlerliste"
         ;
      value $HeaderText_en
         "\brief"           = "Detailed Description"
         "\details"         = "Detailed Description"
         "\author"          = "Author"
         "\date"            = "Date"
         "\sa"              = "See also"
         "\bug"             = "Bug"
         "\test"            = "Test"
         "\todo"            = "To Do"
         "\version"         = "Version"
         "\param"           = "Parameters"
         "\return"          = "Return"
         "\ret_val"         = "Return value"
         "\remark"          = "Comment"
         "\copyright"       = "Copyright"
         "_label_todolist_" = "To Do list"
         "_label_testlist_" = "Test list"
         "_label_buglist_"  = "Bug list"
         ;
      value $TagSort
         "\brief"     = "000"
         "\details"   = "000"
         "\author"    = "002"
         "\date"      = "003"
         "\sa"        = "004"
         "\bug"       = "005"
         "\test"      = "006"
         "\todo"      = "007"
         "\version"   = "001"
         "\param"     = "011"
         "\ret_val"   = "012"
         "\return"    = "009"
         "\remark"    = "008"
         "\copyright" = "00A"
         ;
   run;

   %*** Get all macros to be documented ***;
   %_dir(
       i_path=&g_sasunit.
      ,i_recursive=0
      ,o_out=work.macros0
   );
   data &syslast;
      length pgm_path $400;
      set &syslast.;
      pgm_path="&g_sasunit.";
   run;
   %do i=1 %to 9;
      %if ("&&g_sasautos&i." ne "") %then %do;
         %_dir(
             i_path=&&g_sasautos&i.
            ,i_recursive=0
            ,o_out=work.macros&i.
         );
         data &syslast;
            length pgm_path $400;
            set &syslast.;
            pgm_path="&&g_sasautos&i.";
         run;
      %end;
   %end;
   data work.macros;
      set work.macros0
      %do i=1 %to 9;
         %if ("%cmpres(&&g_sasautos&i.)" ne "") %then %do;
           work.macros&i. 
         %end;
      %end;
      ;
      MacroName = resolve ('%_stdpath(' !! trim(pgm_path) !! ',' !! trim(filename) !! ')');
   run;

   proc sql noprint;
      select count (*) into :l_anzMacros from work.macros;
   quit;

   %do i=1 %to &l_anzMacros.;
      %local l_macroPath&i. l_macroName&i.;
   %end;

   proc sql noprint;
      select pgm_path  into :l_macroPath1-:l_macroPath%cmpres(&l_anzMacros.) from work.macros;
      select MacroName into :l_macroName1-:l_macroName%cmpres(&l_anzMacros.) from work.macros;
   quit;

   options nocenter;

   %let l_outputPath = %_abspath(&g_root.,&g_target.)/rep;

   %do i=1 %to &l_anzMacros;

      %_scanHeader (MacroName  = &&l_macroName&i..
                   ,FilePath   = &&l_macroPath&i..
                   ,LiboutDoc  = WORK
                   ,DataOutDoc = _Pgm&i.
                   ,i_language = &i_language.
                   );

      data work._pgmsrc&i.;
         length Text $400 CommentOpen idxCommentOpen idxCommentClose 8;
         retain CommentOpen 0;
         infile "&&l_macroPath&i../&&l_macroName&i..";
         input;
         Text=_INFILE_;
         idxCommentOpen=index (Text, '');
         if (idxCommentClose > 0) then do;
            CommentOpen=0;
         end;
         keep Text;
      run;

      title j=c "Program Documentation for Macro &&l_macroName&i..";

      ods html4 file="&l_outputPath./pgm_%scan(&&l_macroName&i..,1,%str(.)).html" style=styles.sasunit stylesheet=(url="css/SAS_SASUnit.css");
      %_reportPgmHeader (i_lib=WORK, i_data=_Pgm&i., i_language=&i_language.);

      title j=c "Source Code Documentation for Macro &&l_macroName&i..";

      proc report data=work._pgmsrc&i. nowd missing 
         style(report)=blindTable
         style(column)=blindFixedFontData
         style(header)=blindHeader
         style(lines)=blindCaption [textalign=left]
         ;

         column Text;

         define Text / " ";
      run;

      %_closeHtmlPage;

   %end;
   
   ods html4 file="&l_outputPath./__PgmDoc_Lists.html" style=styles.sasunit stylesheet=(url="css/SAS_SASUnit.css"); 

   %PrintDocList(lib=WORK, data=_ToDoDoc, title=%sysfunc (putc (_label_todolist_, $Headertext_&i_language..)));
   %PrintDocList(lib=WORK, data=_TestDoc, title=%sysfunc (putc (_label_testlist_, $Headertext_&i_language..)));
   %PrintDocList(lib=WORK, data=_BugDoc,  title=%sysfunc (putc (_label_buglist_,  $Headertext_&i_language..)));

   ods _all_ close;

   options center;
%mend;

%macro PrintDocList (lib=, data=, title=);
   title "Listen für das Reporting";
   title2 "&title.";
   proc sort data=&lib..&data.;
      by macroname obs_sort;
   run;
   proc report data=&lib..&data. nowd missing
      style(header)=blindHeader
      style(lines)=blindCaption [textalign=left]
      ;

      column macroname dummy obs_sort new_description;

      define macroname / group noprint;
      define obs_sort / group noprint;
      define dummy / display style(column)=blinddata;
      define new_description / display;

      compute before macroname;
         line macroname $80.;
      endcomp;
      compute after macroname;
         line "^_^_^_^_";
      endcomp;
   run;
%mend;