_render_assertlibraryrep.sas

Go to the documentation of this file.

 
%macro _render_assertLibraryRep (i_assertype=
                                ,i_repdata  =
                                ,i_scnid    =
                                ,i_casid    =
                                ,i_tstid    =
                                ,o_html     = 0
                                ,o_path     =
                                );

   %local l_path;

   title;footnote;

   %_getTestSubfolder (i_assertType=assertLibrary
                      ,i_root      =&g_target./tst
                      ,i_scnid     =&i_scnid.
                      ,i_casid     =&i_casid.
                      ,i_tstid     =&i_tstid.
                      ,r_path      =l_path
                      );

   libname _test "&l_path";

   %if (&o_html.) %then %do;
      ODS HTML4 FILE="&o_path/_&i_scnid._&i_casid._&i_tstid._library_exp.html" 
                style=styles.SASUnit 
                stylesheet=(url="css/SAS_SASUnit.css")
                encoding="&g_rep_encoding.";
   %end;

   %_reportFooter(o_html=&o_html.);

   %if (%sysfunc (libref(_test))=0) %then %do;
      TITLE "&g_nls_reportLibrary_006";
      PROC DOCUMENT NAME=_test._library_exp;
         REPLAY / ACTIVETITLE ACTIVEFOOTN;
      RUN;
   %end;
   %else %do;
      DATA _null_;
         PUT ' ';
      RUN;
   %end;

   %if (&o_html.) %then %do;
      %_closeHtmlPage;
      ODS HTML4 FILE="&o_path/_&i_scnid._&i_casid._&i_tstid._library_act.html" 
                style=styles.SASUnit 
                stylesheet=(url="css/SAS_SASUnit.css")
                encoding="&g_rep_encoding.";
   %end;
   %if (%sysfunc (libref(_test))=0) %then %do;
      PROC DOCUMENT NAME=_test._library_act;
         REPLAY / ACTIVETITLE ACTIVEFOOTN;
      QUIT;
   %end;
   %else %do;
      DATA _null_;
         PUT ' ';
      RUN;
   %end;

   %if (&o_html.) %then %do;
      %_closeHtmlPage;
      ODS HTML4 FILE="&o_path/_&i_scnid._&i_casid._&i_tstid._library_rep.html" 
                style=styles.SASUnit 
                stylesheet=(url="css/SAS_SASUnit.css")
                encoding="&g_rep_encoding.";
   %end;
   
   %if (%sysfunc (exist (_test._library_rep, DATA))) %then %do;
      %local l_LibraryCheck l_CompareCheck l_id l_ExcludeList;
    
      %*** format results for report ***;
      data WORK._library_rep;
         Length resultColumn $400;
         set _test._library_rep;
         %_render_iconColumn (i_sourceColumn=CompareFailed
                             ,o_html=&o_html.
                             ,o_targetColumn=resultColumn
                             );
      run;
    
      proc sql noprint;
         select    i_LibraryCheck,  i_CompareCheck,  i_id,  i_ExcludeList 
             into :l_LibraryCheck, :l_CompareCheck, :l_id, :l_ExcludeList
         from _test._library_rep (obs=1);
      quit;

      options missing=' ';
      TITLE " ";
      Title2 h=3 "LibraryCheck=%trim(&l_LibraryCheck.) - CompareCheck=%trim(&l_CompareCheck.)";
      %if (&l_id. ne _NONE_) %then %do;
         Title3 h=3 "ID-Columns: %trim (&l_id.)";
      %end;
      %if (&l_ExcludeList. ne _NONE_) %then %do;
         Title4 h=3 "&g_nls_reportLibrary_002: %trim (&l_ExcludeList.)";
      %end;
      proc report data=WORK._library_rep nowd missing
         style (column)={vjust=center};
         columns memname
                 ("&g_nls_reportLibrary_003" CmpLibname CmpObs CmpNVar)
                 ("&g_nls_reportLibrary_004" BaseLibname BaseObs BaseNVar)
                 resultColumn
         ;
         define memname / id style={font_weight=bold foreground=black};
         define resultColumn / "&g_nls_reportLibrary_005" style(column)={background=white};
      run;
      options missing=.;
   %end;
   %else %do;
      DATA _null_;
         PUT ' ';
      RUN;
   %end;
   %if (&o_html.) %then %do;
      %_closeHtmlPage;
   %end;
      
   LIBNAME _test;

   title;footnote;
%MEND _render_assertLibraryRep;