regression_test.sas

Go to the documentation of this file.

 
/*-- Compare linear regression between Excel and SAS -------------------------*/

%initTestcase(i_object=regression.sas, i_desc=compare linear regression between Excel and SAS)
%macro SetXLSType;
   %if (&sysver=9.1) %then EXCEL; %else XLS;
%mend;
proc import datafile="&g_testdata/regression.xls" dbms=%SetXLSType out=work.data replace;
   RANGE="data";
run;
data refdata (rename=(yhat=est)) testdata(drop=yhat); 
   set work.data; 
   format _all_;
run; 
proc import datafile="&g_testdata/regression.xls" dbms=%SetXLSType out=refparm replace;
   RANGE="parameters";
run;
   
%regression(data=testdata, x=x, y=y, out=aus, yhat=est, parms=parameters, report=&g_work/report1.rtf)

proc sql noprint; 
   select intercept into :intercept_sas from parameters; 
   select put (x, best12.) into :slope_sas from parameters; 
   select put (e, best12.) into :slope_xls from refparm; 
   select f into :intercept_xls from refparm; 
quit; 

%assertReport(i_actual=&g_work/report1.rtf, i_expected=&g_testdata/regression.xls,
              i_desc=please compare SAS chart with Excel chart)

%assertColumns(i_actual=aus, i_expected=refdata, i_desc=compare estimated values, i_fuzz=1E-10)

%assertEquals(i_actual=&intercept_xls, i_expected=&intercept_sas, i_desc=compare intercept parameter)
%assertEquals(i_actual=&slope_xls, i_expected=&slope_sas, i_desc=compare slope parameter)
%assertPerformance(i_expected=5, i_desc=regression calculation should be done within 5 seconds.)