asserttableexists.sas

Go to the documentation of this file.

 
%MACRO assertTableExists (i_libref  =
                         ,i_memname =
                         ,i_target  = DATA
                         ,i_desc    = Check for existence of a specific dataset
                         ,i_not     = 0
                         );

   /*-- verify correct sequence of calls-----------------------------------------*/
   %GLOBAL g_inTestcase;
   %IF &g_inTestcase EQ 1 %THEN %DO;
      %endTestcall;
   %END;
   %ELSE %IF &g_inTestcase NE 2 %THEN %DO;
      %PUT &g_error.(SASUNIT): assert must be called after initTestcase;
      %RETURN;
   %END;

   %LOCAL l_dsname l_libref_ok l_table_exist l_result l_date l_suffix l_errMsg;
   %LET l_dsname =%sysfunc(catx(., &i_libref, &i_memname));
   %LET l_table_exist = -1;
   %LET l_result=2;
   %LET l_date =;

   %*************************************************************;
   %*** Check preconditions                                   ***;
   %*************************************************************;
   
   %*** check for valid libref ***;
   %LET l_libref_ok=%sysfunc (libref (&i_libref.));
   %IF &l_libref_ok. NE 0 %THEN %DO;
      %LET l_errMsg=Libref &i_libref. is invalid!;
      %goto Update;
   %END;
    
   %*** check if i_target is valid ***;
   %LET i_target=%sysfunc(upcase(&i_target));
   %IF not(&i_target=DATA or &i_target=VIEW or &i_target=CATALOG) %THEN %DO;
      %LET l_table_exist = -2;
      %LET l_errMsg=%bquote(Invalid value for parameter i_target (&i_target.)!);
      %goto Update;
   %END;

   %*************************************************************;
   %*** start tests                                           ***;
   %*************************************************************;
   
   %IF %sysfunc(exist(&l_dsname, &i_target)) %THEN %DO;
      %LET l_table_exist=1;
      %PUT &g_note.(SASUNIT): &i_target. &l_dsname. exists.;
      %LET l_errMsg=&i_target &l_dsname exists;

      %*** get creation und modification date of tested member ***;
      data _null_ ;
         length _crdate _modate $20;
         dsid=open("&l_dsname") ;
         _crdate = attrn(dsid,'CRDTE');
         _modate = attrn(dsid,'MODTE');
         dsid=close(dsid) ;
         call symput('l_date',catt("#",_crdate,"#",_modate));
      run ;
   %END;
   %ELSE %DO;
      %PUT &g_note.(SASUNIT): &i_target. &l_dsname. does not exist.;
      %LET l_errMsg=&i_target &l_dsname does not exist;
      %LET l_table_exist=0;
   %END;

   %LET l_result = %eval(1 - &l_table_exist.);
   %LET l_suffix=%str(, but it should exist!);
   %IF (&i_not) %THEN %DO;
      %LET l_result = %eval(1 - &l_result.);
      %LET l_suffix=%str(, but it should not exist!);
   %END;
   %LET l_errMsg =&l_errMsg.&l_suffix.;
   %LET l_result = %eval(&l_result.*2);

   %Update:;
   %_asserts(i_type     = assertTableExists
            ,i_expected = %str(&i_target.:&l_dsname.:&i_not.)
            ,i_actual   = %str(&l_table_exist.&l_date.)
            ,i_desc     = &i_desc.
            ,i_result   = &l_result.
            ,i_errMsg   = &l_errMsg.
            )

%MEND assertTableExists;