assertlog.sas

Go to the documentation of this file.

 
%MACRO assertLog (i_errors   = 0
                 ,i_warnings = 0
                 ,i_desc     = Scan log for errors
                 );

   /*-- verify correct sequence of calls-----------------------------------------*/
   %GLOBAL g_inTestcase;
   %IF &g_inTestcase EQ 1 %THEN %DO;
      %endTestcall;
   %END;
   %ELSE %IF &g_inTestcase NE 2 %THEN %DO;
      %PUT &g_error.(SASUNIT): assert must be called after initTestcase;
      %RETURN;
   %END;

   %LOCAL l_casid l_error_count l_warning_count l_result l_errMsg;
   %LET l_errMsg=;

   PROC SQL NOPRINT;
   /* determine number of the current test case */
      SELECT max(cas_id) INTO :l_casid FROM target.cas WHERE cas_scnid = &g_scnid;
   QUIT;

   %IF &l_casid = . OR &l_casid = %THEN %DO;
      %PUT &g_error.(SASUNIT): assert must not be called before initTestcase;
      %RETURN;
   %END;

   /* Scan Log */
   %_checklog (
       i_logfile = &g_log/%sysfunc(putn(&g_scnid,z3.))_%sysfunc(putn(&l_casid,z3.)).log
      ,i_error   = &g_error
      ,i_warning = &g_warning
      ,r_errors  = l_error_count
      ,r_warnings= l_warning_count
   )

   %LET l_result = %eval ((
         &l_error_count   NE &i_errors
      OR &l_warning_count NE &i_warnings
      )*2);

   %IF (&l_result. EQ 2) %THEN %DO;
      %LET l_errmsg=%bquote(expected &i_errors. error(s) and &i_warnings. warning(s), but actually there are &l_error_count. error(s) and &l_warning_count warning(s));
   %END;

   %_asserts(i_type     = assertLog
            ,i_expected = %str(&i_errors#&i_warnings)
            ,i_actual   = %str(&l_error_count#&l_warning_count)
            ,i_desc     = &i_desc
            ,i_result   = &l_result
            ,i_errMsg   = &l_errMsg
            )

%MEND assertLog;