_sasunit_checkscenario.sas

Go to the documentation of this file.

 
/* change history
   15.12.2007 AM  Neuerstellung 
*/ 

%MACRO _sasunit_checkScenario(
   i_scnfile = 
  ,i_changed = 
  ,i_dir     = 
  ,r_scnid   = l_scnid
  ,r_run     = l_run
);

%local d_pgm;
%_sasunit_tempFileName(d_pgm)

/*-- set default return value ------------------------------------------------*/
%let &r_scnid=;
%let &r_run=0; 

/*-- standardize absolute path -----------------------------------------------*/
%local l_scnfile;
%let l_scnfile = %_sasunit_stdPath (&g_root, &i_scnfile);

/*-- determine time of last execution of test scenario -----------------------*/
%local ll_scnid l_lastrun;
%let l_lastrun=0;
%let ll_scnid=0;
proc sql noprint;
   select scn_id, compress(put(scn_start,best32.)) into :ll_scnid, :l_lastrun
   from target.scn
   where upcase(scn_path) = "%upcase(&l_scnfile)";
quit;

/*-- execute, if scenario not found or found and changed ---------------------*/
%if &l_lastrun<&i_changed %then %do;
   %put _sasunit_checkScenario <1>;
   %let &r_scnid = &ll_scnid;
   %let &r_run = 1;
   %goto exit;
%end;

/*-- determine units under test in autocall libraries and their change dtime -*/
%local l_pgmcount;
%let l_pgmcount=0;
proc sql noprint;
   select count(*) into :l_pgmcount
   from target.cas
      left join &i_dir dir 
         on upcase(cas.cas_pgm) = upcase(scan(dir.filename,-1,'/'))
            and cas.cas_auton = dir.auton
   where cas.cas_scnid = &ll_scnid
      and (&l_lastrun<dir.changed or dir.changed=.)
      and cas.cas_auton ne .
   ;
quit;

/*-- execute, if at least one unit under test is newer or is missing ---------*/
%if &l_pgmcount %then %do;
   %put _sasunit_checkScenario <2>;
   %let &r_scnid = &ll_scnid;
   %let &r_run = 1;
   %goto exit;
%end;

/*-- look for units under test not in autocall libraries ---------------------*/
proc sql noprint;
   create table &d_pgm as
      select cas.cas_pgm
      from target.cas
      where cas.cas_scnid = &ll_scnid
         and cas.cas_auton=.
   ;
quit;

/*-- do not execute if none found --------------------------------------------*/
%if %_sasunit_nobs(&d_pgm) = 0 %then %do;
   %put _sasunit_checkScenario <3>;
   %let &r_scnid = &ll_scnid;
   %let &r_run = 0;
   %goto exit;
%end;

/*-- determine last modification dtime for those units under test ------------*/
%local i;
%do i=1 %to %_sasunit_nobs(&d_pgm);
   %local l_pgm&i;
%end;
data _null_;
   set &d_pgm;
   call symput ('l_pgm' !! compress(put(_n_,8.)), trim(cas_pgm));
   call symput ('l_pgmcount', compress(put(_n_,8.)));
run;

%do i=1 %to &l_pgmcount;
   %let l_pgm&i = %_sasunit_absPath(&g_root,&&l_pgm&i);
   %_sasunit_dir(i_path=&&l_pgm&i, o_out=&d_pgm)
   
   %local l_pgmchanged;
   %let l_pgmchanged=0;
   proc sql noprint;
      select compress(put(changed,best32.)) into :l_pgmchanged
         from &d_pgm
      ;
   quit;

   /*-- execute scenario, if unit under test newer or not found --------------*/
   %if &l_lastrun < &l_pgmchanged or &l_pgmchanged=0 %then %do;
      %put _sasunit_checkScenario <4>;
      %let &r_scnid = &ll_scnid;
      %let &r_run = 1;
      %goto exit;
   %end;

%end;

/*-- do not execute scenario -------------------------------------------------*/
%put _sasunit_checkScenario <5>;
%let &r_scnid = &ll_scnid;
%let &r_run = 0;

%exit:
/*-- tidy up -----------------------------------------------------------------*/
proc datasets nolist nowarn;
   delete %scan(&d_pgm,2,.);
quit;

%MEND _sasunit_checkScenario;