regression_test.sas

Go to the documentation of this file.

 
/*-- Compare linear regression between Excel and SAS -------------------------*/

%macro onlywin;
%if &sysscp ne WIN %then %do;
   %initTestcase(i_object=regression.sas, i_desc=This test scenario will only run under SAS for Windows)
   endsas;
%end;
%else %do;
   %initTestcase(i_object=regression.sas, i_desc=Compare linear regression between Excel and SAS)
%end;
%mend onlywin;
%onlywin;

libname testdata excel "&g_testdata/regression.xls";
data refdata (rename=(yhat=est)) testdata(drop=yhat); 
   set testdata.data; 
run; 
data refparm; 
   set testdata.parameters;
run; 
libname testdata;
   
%regression(data=testdata, x=x, y=y, out=aus, yhat=est, parms=parameters, report=&g_work\report1.rtf)

proc sql noprint; 
   select intercept into :intercept_sas from parameters; 
   select x into :slope_sas from parameters; 
   select f1 into :slope_xls from refparm; 
   select f2 into :intercept_xls from refparm; 
quit; 

%assertReport(i_actual=&g_work/report1.rtf, i_expected=&g_testdata/regression.xls,
              i_desc=please compare SAS chart with Excel chart)

%assertColumns(i_actual=aus, i_expected=refdata, i_desc=compare estimated values, i_fuzz=1E-10)

%assertEquals(i_actual=&intercept_xls, i_expected=&intercept_sas, i_desc=compare intercept parameter)
%assertEquals(i_actual=&slope_xls, i_expected=&slope_sas, i_desc=compare slope parameter)

---